topcat 姍舞之間的極度凝聚

    Protected Sub gvOrders_RowDataBound(ByVal sender As Object, ByVal e As System.Web.UI.WebControls.GridViewRowEventArgs) Handles gvOrders.RowDataBound
        If Not (ViewState("cOrderID") Is Nothing) Then
            If e.Row.RowType = DataControlRowType.DataRow Then
                Dim drv As DataRowView = e.Row.DataItem
                Dim OrderID As String = CStr(ViewState("cOrderID"))
                '判斷訂單編號相同的Row才要處理
                If CStr(drv.Item("OrderID")) = OrderID Then
                    '取得連接字串
                    Dim ConnStr As String = Web.Configuration.WebConfigurationManager.ConnectionStrings("NWind").ConnectionString
                    '建立DataTable物件
                    Dim Dt As New DataTable
                    '建立Connection
                    Using Conn As New SqlConnection(ConnStr)
                        '設定查詢語法
                        Dim SqlTxt As String = ""
                        SqlTxt += " SELECT * "
                        SqlTxt += " FROM [Order Details] "
                        SqlTxt += " WHERE OrderID = @OrderID "
                        '建立Command物件
                        Dim Cmmd As New SqlCommand(SqlTxt, Conn)
                        '設定參數
                        Cmmd.Parameters.AddWithValue("@OrderID", ViewState("cOrderID"))
                        '建立DataAdapter
                        Dim Da As New SqlDataAdapter(Cmmd)
                        Da.Fill(Dt)
                    End Using
                    '建立Detail的GridView
                    Dim gvDetail As New GridView
                    '指定資料來源
                    gvDetail.DataSource = Dt
                    '設定自動產生欄位
                    gvDetail.AutoGenerateColumns = True
                    '資料繫結
                    gvDetail.DataBind()

                    '產生新的GridViewRow
                    Dim gvRow As New GridViewRow(0, -1, DataControlRowType.DataRow, DataControlRowState.Normal)
                    '建立一個Cell
                    Dim tCell As New TableCell
                    tCell.Controls.Add(gvDetail)
                    '設定合併Cell
                    tCell.Attributes.Add("colspan", "7")
                    '設定置中
                    tCell.Attributes.Add("align", "center")
                    'Cell放入GridViewRow
                    gvRow.Cells.Add(tCell)
                    'GridViewRow放到GridView中
                    e.Row.Parent.Controls.AddAt(e.Row.RowIndex + 2, gvRow)
                End If
            End If
        End If
    End Sub